Konfigurera SQL Server aktiverad av Azure Arc

Applies to:SQL Server

Varje Azure Arc-aktiverad server innehåller en uppsättning egenskaper som gäller för alla SQL Server instanser som är installerade på servern. Du kan konfigurera dessa egenskaper när Azure-tillägget för SQL Server har installerats på datorn. Egenskaperna börjar dock bara gälla om en SQL Server instans eller instanser har installerats. I Azure-portalen visar fönstret Overview för SQL Server som aktiveras av Azure Arc hur SQL Server-konfigurationen påverkar en viss instans.

Förutsättningar

• Du har rollen Contributor i minst en av de Azure prenumerationer som din organisation har skapat. Lär dig hur du skapar en ny faktureringsprenumeration.

• Du har rollen Contributor för resursgruppen där SQL Server-instansen registreras. Mer information finns i Hanterade Azure-resursgrupper.

• Resursleverantörer Microsoft.AzureArcData och Microsoft.HybridCompute registreras i varje prenumeration som du använder för SQL Server fakturering efter användning.

Registrera resursprovidrar

Om du vill registrera resursprovidrar använder du någon av följande metoder:

Register-AzResourceProvider -ProviderNamespace Microsoft.AzureArcData

az provider register --namespace 'Microsoft.AzureArcData'

Ändra SQL Server konfiguration

Du kan använda Azure-portalen, Azure PowerShell eller Azure CLI för att ändra alla eller vissa konfigurationsinställningar på en specifik Azure Arc-aktiverad server till önskat tillstånd.

Om du vill ändra SQL Server konfiguration för ett större omfång (till exempel en resursgrupp, en prenumeration eller flera prenumerationer) med ett enda kommando använder du powershell-skriptet modify-license-type.ps1. Den publiceras som ett exempel på SQL Server med öppen källkod och innehåller stegvisa instruktioner.

Vi rekommenderar att du kör skriptet från Azure Cloud Shell eftersom:

• Den har de nödvändiga Azure PowerShell modulerna förinstallerade.
• Den autentiserar dig automatiskt.

Mer information finns i Kör skriptet med hjälp av Cloud Shell.

# Updated settings object
$Settings = @{
    SqlManagement = @{ IsEnabled = $true };
    ExcludedSqlInstances = @( "Foo", "Bar");
    LicenseType = "PAYG";
    enableExtendedSecurityUpdates = $True;
    esuLastUpdatedTimestamp = [DateTime]::UtcNow.ToString('yyyy-MM-ddTHH:mm:ss.fffZ')
}

# Command stays the same as before; only Settings is changed
New-AzConnectedMachineExtension -Name "WindowsAgent.SqlServer" -ResourceGroupName { your resource group name } -MachineName { your machine name } -Location { azure region } -Publisher "Microsoft.AzureData" -Settings $Settings -ExtensionType "WindowsAgent.SqlServer"

az connectedmachine extension update --machine-name "simple-vm" -g "<resource-group>" --name "WindowsAgent.SqlServer" --type "WindowsAgent.SqlServer" --publisher "Microsoft.AzureData" --settings '{"LicenseType":"PAYG", "SqlManagement": {"IsEnabled":true}}'

Prenumerera på utökade säkerhetsuppdateringar i stor skala med hjälp av Azure Policy

Du kan aktivera ESU-prenumerationen på flera Azure Arc-aktiverade datorer med hjälp av en Azure Policy definition med namnet Prenumerera berättigade Arc-aktiverade SQL Servers-instanser till utökade säkerhetsuppdateringar.

När du skapar en tilldelning av den här principdefinitionen till ett valfritt omfång aktiverar den ESUs på alla Azure Arc-aktiverade datorer som har Azure-tillägget för SQL Server installerat. Om någon av dessa datorer har en kvalificerad SQL Server instans aktiveras ESU-prenumerationen omedelbart.

Använd följande steg för att aktivera den här principen:

1. I Azure-portalen går du till Azure Policy och väljer sedan Definitions.

2. Sök efter Anslut berättigade Arc-aktiverade SQL-serverinstanser till Utökade säkerhetsuppdateringar och högerklicka på principen.

3. Välj Tilldela princip.

4. Välj en prenumeration och eventuellt en resursgrupp som omfång.

5. Kontrollera att principtillämpningen är inställd på Aktiverad.

6. På fliken Parametrar anger du värdet för Aktivera utökade säkerhetsuppdateringar till True.

7. På fliken Åtgärd:

   1. Välj Skapa reparationsaktivitet för att principen ska tillämpas på befintliga resurser. Om du inte väljer det här alternativet tillämpas principen endast på de nyligen skapade resurserna.
   2. Välj Skapa en hanterad identitet och välj sedan Systemtilldelad hanterad identitet (rekommenderas) eller Användare tilldelad hanterad identitet, som har behörigheterna Azure för SQL Server Deployment och Reader.
   3. Välj identitetens plats.

8. Välj Granska + Skapa.

9. Välj Skapa.

Fråga SQL Server konfigurationen

Du kan använda Azure Resource Graph för att fråga SQL Server konfigurationsinställningarna inom ett valt omfång. Se följande exempel.

Hämta antalet efter licenstyp

Det här exemplet returnerar antalet efter licenstyp:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| extend licenseType = iff(properties.settings.LicenseType == '', 'Configuration needed', properties.settings.LicenseType)
| summarize count() by tostring(licenseType)

Identifiera instanser där licenstypen är odefinierad

Den här frågan returnerar en lista över instanser där licenstypen är null:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| where isnull(properties.settings.LicenseType)
| project ['id'], resourceGroup, subscriptionId

Lista konfigurationsinformation för varje SQL Server instans

Den här frågan identifierar många detaljer om varje instans, inklusive licenstyp, ESU-inställning och aktiverade funktioner:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| extend machineIdHasSQLServerDiscovered = id
| project name, machineIdHasSQLServerDiscovered, resourceGroup, subscriptionId
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), "")
    | project Extension_State = properties.provisioningState,
    License_Type = properties.settings.LicenseType,
    ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == true,"enabled","disabled"), ""),
    Extension_Version = properties.instanceView.typeHandlerVersion,
    Excluded_instances = properties.ExcludedSqlInstances,
    Purview = iff(notnull(properties.settings.ExternalPolicyBasedAuthorization),"enabled",""),
    Entra = iff(notnull(properties.settings.AzureAD),"enabled",""),
    BPA = iff(notnull(properties.settings.AssessmentSettings),"enabled",""),
    machineIdHasSQLServerExtensionInstalled)on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isnotempty(machineIdHasSQLServerExtensionInstalled)
| project-away machineIdHasSQLServerDiscovered, machineIdHasSQLServerExtensionInstalled

Lista Azure Arc-aktiverade servrar med instanser av SQL Server

Den här frågan identifierar Azure Arc-aktiverade servrar med SQL Server instanser som identifieras på dem:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
//| summarize count()

Den här frågan returnerar Azure Arc-aktiverade servrar som har SQL Server instanser, men tillägget Azure Arc SQL Server är inte installerat. Den här frågan gäller endast för Windows servrar.

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| project machineIdHasSQLServerDiscovered = id
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type == "WindowsAgent.SqlServer"
    | project machineIdHasSQLServerExtensionInstalled = substring(id, 0, indexof(id, "/extensions/WindowsAgent.SqlServer")))
on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isempty(machineIdHasSQLServerExtensionInstalled)
| project machineIdHasSQLServerDiscoveredButNotTheExtension = machineIdHasSQLServerDiscovered

Fler exempel på Azure Resource Graph frågor finns i Starter Resource Graph-frågeexempel.

Lista Azure Arc-aktiverade SQL Server instanser som prenumererar på ESU:er

I följande exempel visas hur du kan visa alla berättigade SQL Server 2014-instanser (12.x) och deras ESU-prenumerationsstatus:

resources
| where type == 'microsoft.azurearcdata/sqlserverinstances'
| extend Version = properties.version
| extend Edition = properties.edition
| extend containerId = tolower(tostring (properties.containerResourceId))
| where Version in ("SQL Server 2014")
| where Edition in ("Enterprise", "Standard")
| where isnotempty(containerId)
| project containerId, SQL_instance = name, Version, Edition
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines"
    | extend machineId = tolower(tostring(id))
    | project machineId, Machine_name = name
)
on $left.containerId == $right.machineId
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = tolower(iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), ""))
    | project machineIdHasSQLServerExtensionInstalled,
     Extension_State = properties.provisioningState,
     License_Type = properties.settings.LicenseType,
     ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == 'true',"ENABLED","disabled"), "disabled"),
     Extension_Version = properties.instanceView.typeHandlerVersion
)
on $left.machineId == $right.machineIdHasSQLServerExtensionInstalled
| project-away machineId, containerId, machineIdHasSQLServerExtensionInstalled

Lista Azure Arc-aktiverade servrar som är värdar för en fakturerbar SQL Server instans

Den här frågan identifierar anslutna datorer (virtuella eller fysiska) som är värdar för SQL Server instanser och som kan faktureras eller kräver en licens för SQL Server programvara. Den innehåller information om SQL Server konfiguration, inklusive licenstyp, ESU-inställning, storlek i v-kärnor eller p-kärnor och andra relevanta parametrar.

resources
| where type =~ 'Microsoft.HybridCompute/machines'
| extend status = tostring(properties.status)
| where status =~ 'Connected'
| extend machineID = tolower(id)
| extend VMbyManufacturer = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "VMware" or
    properties.detectedProperties.manufacturer contains_cs "QEMU" or
    properties.detectedProperties.manufacturer contains_cs "Amazon EC2" or
    properties.detectedProperties.manufacturer contains_cs "OpenStack" or
    properties.detectedProperties.manufacturer contains_cs "Hetzner" or
    properties.detectedProperties.manufacturer contains_cs "Mission Critical Cloud" or
    properties.detectedProperties.manufacturer contains_cs "DigitalOcean" or
    properties.detectedProperties.manufacturer contains_cs "UpCloud" or
    properties.detectedProperties.manufacturer contains_cs "oVirt" or
    properties.detectedProperties.manufacturer contains_cs "Alibaba" or
    properties.detectedProperties.manufacturer contains_cs "KubeVirt" or
    properties.detectedProperties.manufacturer contains_cs "Parallels" or
    properties.detectedProperties.manufacturer contains_cs "Bochs" or
    properties.detectedProperties.manufacturer contains_cs "XEN", 1, 0))
| extend VMbyModel = toboolean(iff(
    properties.detectedProperties.model contains_cs "OpenStack" or
    properties.detectedProperties.model contains_cs "Droplet" or
    properties.detectedProperties.model contains_cs "oVirt" or
    properties.detectedProperties.model contains_cs "Hypervisor" or
    properties.detectedProperties.model contains_cs "Virtual" or
    properties.detectedProperties.model contains_cs "BHYVE" or
    properties.detectedProperties.model contains_cs "KVM", 1, 0))
| extend GoogleVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Google" and
    properties.detectedProperties.model contains_cs "Google Compute Engine", 1, 0))
| extend NutanixVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Nutanix" and
    properties.detectedProperties.model contains_cs "AHV", 1, 0))
| extend MicrosoftVM = toboolean(iff(
    properties.detectedProperties.manufacturer contains_cs "Microsoft Corporation" and
    properties.detectedProperties.model contains_cs "Virtual Machine", 1, 0))
| extend billableCores = iff(
    VMbyManufacturer or VMbyModel or GoogleVM or NutanixVM or MicrosoftVM,
    properties.detectedProperties.logicalCoreCount,
    properties.detectedProperties.coreCount)
| join kind=leftouter (
    resources
    | where type =~ 'Microsoft.HybridCompute/machines/extensions'
    | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
    | extend extMachineID = substring(id, 0, indexof(id, '/extensions'))
    | extend extensionId = id
) on $left.id == $right.extMachineID
| join kind=inner (
    resources
    | where type =~ 'microsoft.azurearcdata/sqlserverinstances'
    | extend sqlVersion = tostring(properties.version)
    | extend sqlEdition = tostring(properties.edition)
    | extend is_Enterprise = toint(iff(sqlEdition == "Enterprise", 1, 0))
    | extend sqlStatus = tostring(properties.status)
    | extend licenseType = tostring(properties.licenseType)
    | where sqlEdition in ('Enterprise', 'Standard')
    | where licenseType !~ 'HADR'
    | extend ArcServer = tolower(tostring(properties.containerResourceId))
    | order by sqlEdition
) on $left.machineID == $right.ArcServer
| where isnotnull(extensionId)
| summarize Edition = iff(sum(is_Enterprise) > 0, "Enterprise", "Standard") by machineID, name, resourceGroup, subscriptionId, Status = tostring(properties.status), Model = tostring(properties.detectedProperties.model), Manufacturer = tostring(properties.detectedProperties.manufacturer), License_Type = tostring(properties1.settings.LicenseType), ESU = iff(notnull(properties1.settings.enableExtendedSecurityUpdates), iff(properties1.settings.enableExtendedSecurityUpdates == true, "enabled", "not enabled"), "not enabled"), OS = tostring(properties.osName), Uses_UV = tostring(properties1.settings.UsePhysicalCoreLicense.IsApplied), Cores = tostring(billableCores), Version = sqlVersion, HostType = iff(VMbyManufacturer or VMbyModel or GoogleVM or NutanixVM or MicrosoftVM, "VM", "Physical")
| summarize by name, subscriptionId, resourceGroup, Model, Manufacturer, HostType, License_Type, ESU, OS, Cores, Status
| project Name = name, Model, Manufacturer, HostType, OperatingSystem = OS, Status, HostLicenseType = License_Type, ESU, BillableCores = Cores, SubscriptionID = subscriptionId, ResourceGroup = resourceGroup
| order by Name asc

Hantera den obegränsade virtualiseringsförmånen för SQL Server

Om du vill aktivera obegränsad virtualisering stöder SQL Server som aktiveras av Azure Arc en särskild resurstyp: SQLServerLicense. Du kan använda den här resursen för att licensiera många virtuella datorer med de installerade SQL Server instanserna. Mer information om licensieringsmodellen finns i License SQL Server-instanser med obegränsad virtualisering.

Förutsättningar

Din rollbaserade roll för åtkomstkontroll (RBAC) innehåller följande behörigheter:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

Skapa en SQL Server licens

Om du vill skapa en SQL Server licensresurs använder du någon av följande metoder:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Deactivated",
    "scopeType": "ResourceGroup",
    "licenseCategory": "Core"
}

Uppdatera en SQL Server-licensresurs

Om du vill ändra SQL Server-licensegenskapen (till exempel aktivera den vid ett senare tillfälle) använder du någon av följande metoder:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="activate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Activated"
}

Hantera resurser i omfånget för en p-core-licens

Du kan hantera resurserna i omfånget för en specifik SQL Server licens för fysisk kärna med hjälp av följande steg:

Lista Azure Arc-aktiverade servrar i omfånget för SQL Server-licensen

Den här frågan visar alla Azure Arc-aktiverade servrar i licensomfånget och relevanta egenskaper för var och en:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UsePhysicalCoreLicense.IsApplied
        |order by name asc

Hantera den obegränsade virtualiseringsförmånen för en SQL Server ESU-prenumeration

Om du vill aktivera obegränsad virtualisering för en ESU-prenumeration SQL Server aktiverad av Azure Arc stöder en särskild resurstyp: SqlServerEsuLicenses. Du kan använda den här resursen för att aktivera en ESU-prenumeration för en uppsättning fysiska värdar med ett obegränsat antal virtuella datorer som kör SQL Server instanser som inte stöds. Mer information om licensieringsmodellen finns i Prenumerera på SQL Server ESUs med hjälp av fysiska kärnor med obegränsad virtualisering.

Förutsättningar

Din RBAC-roll innehåller följande behörigheter:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

Skapa en SQL Server ESU-licensresurs

Om du vill skapa en SQL Server ESU-licensresurs använder du någon av följande metoder:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Active",
    "scopeType": "ResourceGroup",
    "version": "2014"
}

Uppdatera en SQL Server ESU-licensresurs

Om du vill ändra licensegenskaperna för SQL Server ESU (till exempel avsluta prenumerationen) använder du någon av följande metoder:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="terminate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Terminated"
}

Hantera resurser inom ramen för en ESU P-core-licens

Du kan hantera resurserna i omfånget för en specifik SQL Server ESU-licens med hjälp av följande steg:

Lista Azure Arc-aktiverade servrar i omfånget för en SQL Server ESU-licens

Den här frågan visar alla Azure Arc-aktiverade servrar i licensomfånget och relevanta egenskaper för var och en:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UseEsuPhysicalCoreLicense.IsApplied
        |order by name asc

Uppgradera tillägget

För att fastställa versionen av den aktuella utgåvan av tillägget, läs versionsinformationen.

Om du vill kontrollera versionen av tillägget använder du följande PowerShell-kommando:

azcmagent version

För att förenkla tilläggsuppgraderingar måste du aktivera automatiska uppdateringar. Du kan också uppgradera tillägget manuellt med hjälp av Azure-portalen, PowerShell och Azure CLI.

Install-Module -Name Az.ConnectedMachine

# Variables 
$Subscription_Id = "<SubscriptionId>" 
$ResourceGroup = "<ResourceGroup>" 
$MachineName = "<MachineName>" 
$ExtensionName = "WindowsAgent.SqlServer" 
$Publisher = "Microsoft.AzureData" 
$TargetVersion = "<LatestVersion>"  # Example: 1.1.3211.337 

# Upgrade the extension 
Set-AzContext -Subscription $SubscriptionId 

$params = @{
  ResourceGroupName = $ResourceGroup
  MachineName = $MachineName
  Name = $ExtensionName
  Publisher = $Publisher
  Type = $ExtensionName
  TypeHandlerVersion = $TargetVersion
}

Update-AzConnectedMachineExtension @params

az extension add --name connectedmachine 

# Variables 
Subscription_Id="<SubscriptionId>" 
Resource_Group="<ResourceGroup>" 
Machine_Name="<ArcEnabledServerName>" 
Extension_Name="WindowsAgent.SqlServer" 
Publisher="Microsoft.AzureData" 
Target_Version="<LatestVersion>"  # Example: 1.1.3211.337 

# Upgrade the extension 

az account set --subscription $Subscription_Id 
az connectedmachine extension update \ 
    --resource-group $Resource_Group \ 
    --machine-name $Machine_Name \ 
    --name $Extension_Name \ 
    --publisher $Publisher \ 
    --type $Extension_Name \ 
    --type-handler-version $Target_Version 

Mer information om hur du uppgraderar Azure-tillägget för SQL Server finns i Upgrade-tillägget.

Relaterat innehåll

• Hantera licensiering och fakturering av SQL Server som aktiveras av Azure Arc
• SQL Server 2022-prissättning
• SQL Server installationsguide
• Vad är utökade säkerhetsuppdateringar för SQL Server?
• Vanliga frågor och svar
• Konfigurera automatiska uppdateringar för SQL Server som aktiveras av Azure Arc