Metodtips för FinOps för webben

Den här artikeln beskriver en samling beprövade FinOps-metoder för webbtjänster. Den innehåller strategier för att optimera kostnader, förbättra effektiviteten och använda Azure Resource Graph-frågor (ARG) för att få insikter om dina webbresurser. Genom att följa dessa metoder kan du se till att dina webbtjänster är kostnadseffektiva och anpassade till organisationens ekonomiska mål.

App-tjänst

Följande avsnitt innehåller ARG-frågor för App Service. De här frågorna hjälper dig att få insikter om dina App Service-resurser och se till att de är konfigurerade med lämpliga inställningar. Genom att analysera App Service-planer och visa rekommendationer från Azure Advisor kan du optimera dina App Service-resurser för kostnadseffektivitet.

Fråga: Webbprogramstatus

Den här ARG-frågan hämtar status och grundläggande information om webbprogram i Din Azure-miljö.

Kategori

Övervakning

Fråga

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Ta bort tomma App Service-planer

Rekommendation: Ta bort App Service-planer som inte är värdar för några appar eller funktioner för att undvika onödiga avgifter.

Om tomma App Service-planer

App Service-planer definierar beräkningsresurserna för dina webbappar. Betalda planer debiteras baserat på deras konfigurerade SKU och antalet instanser, oavsett om några appar finns på dem. Tomma planer kan ackumuleras under utveckling eller när appar flyttas mellan planer. Att ta bort oanvända planer eliminerar onödiga kostnader.

Identifiera tomma App Service-planer

Använd följande ARG-fråga för att identifiera App Service-planer utan värdbaserade appar.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Fråga: Information om App Service-plan

Den här ARG-frågan hämtar detaljerad information om Azure App Service-planer i din Azure-miljö.

Kategori

Resurshantering

Fråga

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Lämna feedback

Låt oss veta hur det går med en snabb granskning. Vi använder dessa granskningar för att förbättra och utöka FinOps-verktyg och -resurser.

Om du letar efter något specifikt kan du rösta på en befintlig eller skapa en ny idé. Dela idéer med andra för att få fler röster. Vi fokuserar på idéer med flest röster.

Relaterat innehåll

Relaterade resurser:

• FinOps Framework

Relaterade lösningar:

• FinOps toolkit Power BI-rapporter
• FinOps-hubbar
• FinOps-arbetsböcker
• Optimeringsmotor