Metodtips för FinOps för Lagring

Den här artikeln beskriver en samling beprövade FinOps-metoder för lagringstjänster. Den innehåller strategier för att optimera kostnader, förbättra effektiviteten och använda Azure Resource Graph-frågor (ARG) för att få insikter om dina lagringsresurser. Genom att följa dessa metoder kan du se till att dina lagringstjänster är kostnadseffektiva och anpassade till organisationens ekonomiska mål.


Säkerhetskopiering

Följande avsnitt innehåller ARG-frågor för säkerhetskopieringstjänster. De här frågorna hjälper dig att få insikter om dina säkerhetskopieringsresurser och se till att de är konfigurerade med lämpliga inställningar. Genom att analysera säkerhetskopieringsobjekt och identifiera inaktiva säkerhetskopieringar kan du optimera dina säkerhetskopieringstjänster för kostnadseffektivitet.

Fråga: Inaktiva säkerhetskopieringar

Den här ARG-frågan analyserar säkerhetskopieringsobjekt i Azure Recovery Services-valv och identifierar alla som inte har säkerhetskopierats på över 90 dagar.

Kategori

Optimering

Fråga

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Sökfråga: Lista Recovery Services-skydd

Den här Arg-frågan (Azure Resource Graph) hämtar information om Azure Recovery Services-valv. Frågan innehåller även information om SKU-nivån, redundansinställningar och andra relevanta metadata.

Kategori

Optimering

Fråga

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Diskar

Azure hanterade diskar är lagringsvolymer på blocknivå som hanteras av Azure och används med virtuella datorer. Hanterade diskar ger hög tillgänglighet, skalbarhet och säkerhet för dina VM-arbetsbelastningar.

Relaterade resurser:

Ta bort diskar som inte är anslutna

Rekommendation: Ta bort eller nedgradera ej anslutna hanterade diskar för att undvika onödiga lagringskostnader.

Om ej anslutna diskar

När en virtuell dator tas bort kanske dess associerade hanterade diskar inte tas bort automatiskt. Dessa ej anslutna (föräldralösa) diskar fortsätter att medföra lagringskostnader beroende på disktyp och storlek. Frågan exkluderar diskar som är i aktivt SAS-överföringsläge eller Azure Site Recovery replik- eller startdiskar, eftersom dessa förväntas vara tillfälligt okopplade.

Note

FinOps-hubbar kan automatiskt identifiera oanslutna diskar. Läs mer.

Identifiera diskar som inte är anslutna

Använd följande ARG-fråga för att identifiera ej anslutna hanterade diskar.

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Fråga: Diskögonblicksbild som är äldre än 30 dagar

Den här ARG-frågan identifierar diskögonblicksbilder som är äldre än 30 dagar.

Kategori

Optimering

Fråga

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Nedgradera premiumögonblicksbilder

Rekommendation: Använd Standard storage för ögonblicksbilder av hanterade diskar i stället för Premium för att minska lagringskostnaderna.

Om premiumsnapshots

Ögonblicksbilder av hanterade diskar som lagras på Premium Storage medför högre kostnader än Standard Storage. I de flesta fall kräver ögonblicksbilder inte prestanda för Premium Storage eftersom de används för säkerhetskopiering och återställning, inte aktiv I/O. Nedgradering till Standard Storage kan avsevärt minska kostnaderna för ögonblicksbilder utan att påverka deras funktioner.

Note

FinOps-hubbar kan automatiskt identifiera ögonblicksbilder med premiumlagring. Läs mer.

Identifiera premiumögonblicksbilder

Använd följande ARG-fråga för att identifiera ögonblicksbilder av hanterade diskar med premiumlagring.

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Lagringskonton

Azure Storage konton ger ett unikt namnområde i Azure för dina data. Lagringskonton har utvecklats genom flera generationer och användning av äldre kontotyper kan begränsa åtkomsten till nyare funktioner och optimeringar.

Relaterade resurser:

Uppgradera äldre lagringskonton

Rekommendation: Uppgradera lagringskonton med GPv1 eller BlobStorage-typ till GPv2 för bättre prisnivåer, funktioner och fortsatt support.

Om äldre lagringskonton

Lagringskonton som använder typen GPv1 eller BlobStorage stöder inte de senaste Azure Storage funktionerna, till exempel åtkomstnivåer för blockblobar, livscykelhanteringsprinciper och oföränderliga principer. GPv2-lagringskonton ger samma funktioner plus ytterligare funktioner till konkurrenskraftiga eller lägre priser. Microsoft rekommenderar att du uppgraderar alla GPv1- och BlobStorage-konton till GPv2.

Note

FinOps-hubbar kan automatiskt identifiera äldre lagringskonton. Läs mer.

Identifiera äldre lagringskonton

Använd följande ARG-fråga för att identifiera lagringskonton som fortfarande använder GPv1- eller BlobStorage-typ.

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Lämna feedback

Låt oss veta hur det går med en snabb granskning. Vi använder dessa granskningar för att förbättra och utöka FinOps-verktyg och -resurser.

Ge återkoppling

Om du letar efter något specifikt kan du rösta på en befintlig eller skapa en ny idé. Dela idéer med andra för att få fler röster. Vi fokuserar på idéer med flest röster.

Rösta på eller föreslå idéer


Relaterat innehåll

Relaterade resurser:

Relaterade lösningar:


  • Last updated on