Snabbstart: Skapa en dedikerad SQL-pool för Azure Synapse Analytics (tidigare SQL DW) med Bicep

Den här Bicep-filen skapar en dedikerad SQL-pool (tidigare SQL DW) med transparent datakryptering aktiverad. Dedikerad SQL-pool (tidigare SQL DW) refererar till de informationslagerfunktioner för företag som är allmänt tillgängliga i Azure Synapse.

Bicep är ett domänspecifikt språk (DSL) som använder deklarativ syntax för att distribuera Azure-resurser. Det ger koncis syntax, tillförlitlig typsäkerhet och stöd för återanvändning av kod. Bicep erbjuder den bästa redigeringsupplevelsen för dina infrastruktur-som-kod-lösningar i Azure.

Förutsättningar

Om du inte har någon Azure-prenumeration skapar du ett kostnadsfritt konto innan du börjar.

Granska Bicep-filen

Bicep-filen som används i den här snabbstarten kommer från Azure-snabbstartsmallar.

@description('The SQL Logical Server name.')
param sqlServerName string = 'sql${uniqueString(resourceGroup().id)}'

@description('The administrator username of the SQL Server.')
param sqlAdministratorLogin string

@description('The administrator password of the SQL Server.')
@secure()
param sqlAdministratorPassword string

@description('The name of the Database.')
param databasesName string

@description('Enable/Disable Transparent Data Encryption')
@allowed([
  'Enabled'
  'Disabled'
])
param transparentDataEncryption string = 'Enabled'

@description('DW Performance Level expressed in DTU (i.e. 900 DTU = DW100c)')
@minValue(900)
@maxValue(54000)
param capacity int

@description('The SQL Database collation.')
param databaseCollation string = 'SQL_Latin1_General_CP1_CI_AS'

@description('Resource location')
param location string = resourceGroup().location

resource sqlServer 'Microsoft.Sql/servers@2023-08-01-preview' = {
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlAdministratorLogin
    administratorLoginPassword: sqlAdministratorPassword
    version: '12.0'
    publicNetworkAccess: 'Enabled'
    minimalTlsVersion: '1.2'
    restrictOutboundNetworkAccess: 'Disabled'
  }
}

resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2023-08-01-preview' = {
  parent: sqlServer
  name: databasesName
  location: location
  sku: {
    name: 'DataWarehouse'
    tier: 'DataWarehouse'
    capacity: capacity
  }
  properties: {
    collation: databaseCollation
    catalogCollation: databaseCollation
    readScale: 'Disabled'
    requestedBackupStorageRedundancy: 'Geo'
    isLedgerOn: false
  }
}

resource encryption 'Microsoft.Sql/servers/databases/transparentDataEncryption@2023-08-01-preview' = {
  parent: sqlServerDatabase
  name: 'current'
  properties: {
    state: transparentDataEncryption
  }
}

resource securityAlertPolicy 'Microsoft.Sql/servers/securityAlertPolicies@2023-08-01-preview' = {
  parent: sqlServer
  name: 'default'
  properties: {
    state: 'Enabled'
  }
}

resource auditingSetting 'Microsoft.Sql/servers/auditingSettings@2023-08-01-preview' = {
  parent: sqlServer
  name: 'default'
  properties: {
    isAzureMonitorTargetEnabled: true
    state: 'Enabled'
    retentionDays: 7
    auditActionsAndGroups: [
      'SUCCESSFUL_DATABASE_AUTHENTICATION_GROUP'
      'FAILED_DATABASE_AUTHENTICATION_GROUP'
      'BATCH_COMPLETED_GROUP'
    ]
  }
}

output location string = location
output name string = sqlServer.name
output resourceGroupName string = resourceGroup().name
output resourceId string = sqlServer.id

Bicep-filen definierar en resurs:

• Microsoft.Sql/servers

Distribuera Bicep-filen

1. Spara Bicep-filen som main.bicep på din lokala dator.

2. Distribuera Bicep-filen med antingen Azure CLI eller Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters sqlAdministratorLogin=<admin-login> databasesName=<db-name> capacity=<int>
   

   Kommentar

   Ersätt <administratörsinloggning> med användarnamnet för administratörsinloggning för SQL-servern. Ersätt <db-name> med namnet på databasen. Ersätt <int> med DW-prestandanivån. Det minsta värdet är 900 och det maximala värdet är 54000. Du uppmanas också att ange sqlAdministratorPassword.

När distributionen är klar bör du se ett meddelande som anger att distributionen lyckades.

Granska distribuerade resurser

Använd Azure Portal, Azure CLI eller Azure PowerShell för att lista de distribuerade resurserna i resursgruppen.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Rensa resurser

När den inte längre behövs använder du Azure Portal, Azure CLI eller Azure PowerShell för att ta bort resursgruppen och dess resurser.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Nästa steg

I den här snabbstarten skapade du en dedikerad SQL-pool (tidigare SQL DW) med Bicep och verifierade distributionen. Mer information om Azure Synapse Analytics och Bicep finns i artiklarna nedan.

• Läs en översikt över Azure Synapse Analytics
• Läs mer om Bicep
• Snabbstart: Skapa Bicep-filer med Visual Studio Code