IteratorStateMachineAttribute Classe

Definição

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Herança

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Atributos

AttributeUsageAttribute SerializableAttribute

Exemplos

O exemplo a seguir mostra como determinar se um método é um método iterador. No exemplo, IsIteratorMethod executa as seguintes etapas:

• Obtém um MethodInfo objeto para o nome do método usando Type.GetMethod.

• Obtém um Type objeto para o atributo usando o Operador GetType.

• Obtém um objeto de atributo para o método e o tipo de atributo usando MethodInfo.GetCustomAttribute. Se GetCustomAttribute retorna Nothing (Visual Basic), o método não contém o atributo.

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Comentários

Você não deve aplicar o IteratorStateMachine atributo aos métodos em seu código. Para métodos no Visual Basic que têm o modificador iterador , o compilador aplicará o IteratorStateMachine atributo no IL que ele emite.

Quando um método (MethodName) no Visual Basic tem o Iterator modificador, o compilador emite IL que inclui uma estrutura de computador de estado. Essa estrutura contém o código no método. Esse IL também contém um método stub (MethodName) que chama o computador de estado. O compilador adiciona o IteratorStateMachine atributo ao método stub para que as ferramentas possam identificar o computador de estado correspondente. Os detalhes do IL emitido podem ser alterados em versões futuras dos compiladores.

Um método iterador executa uma iteração personalizada em uma coleção usando a Yield instrução (Visual Basic) para retornar cada elemento um de cada vez.

Confira também

• AsyncStateMachineAttribute
• StateMachineType