Collection Classe

Definição

public ref class Collection sealed : System::Collections::IList

public ref class Collection sealed : System::Collections::IList, System::Runtime::Serialization::IDeserializationCallback, System::Runtime::Serialization::ISerializable

public sealed class Collection : System.Collections.IList

[System.Serializable]
public sealed class Collection : System.Collections.IList, System.Runtime.Serialization.IDeserializationCallback, System.Runtime.Serialization.ISerializable

type Collection = class
    interface ICollection
    interface IList

[<System.Serializable>]
type Collection = class
    interface ICollection
    interface IList
    interface ISerializable
    interface IDeserializationCallback

Public NotInheritable Class Collection
Implements IList

Public NotInheritable Class Collection
Implements IDeserializationCallback, IList, ISerializable

Herança

Object

Collection

Atributos

SerializableAttribute

Implementações

ICollection IEnumerable IList IDeserializationCallback ISerializable

Exemplos

O exemplo seguinte cria o Collection objeto names e uma caixa de diálogo com a qual o utilizador pode adicionar objetos (nomes) à coleção. Depois, exibe os nomes na coleção e, finalmente, esvazia a coleção sem se deitar fora do Collection objeto em si.

Para ver como isto funciona, escolha o comando Add Class no menu Project e declare uma variável pública chamada instanceName ao nível do módulo nameClass (tipo Public instanceName) para conter os nomes de cada instância. Deixe o nome padrão como nameClass. Copie e cole o código seguinte na secção Geral de outro módulo e depois inicie-o com a instrução classNamer noutro procedimento. (Este exemplo funciona apenas com aplicações anfitriãs que suportam classes.)

Public Class nameClass
    Public instanceName As String
End Class
Sub classNamer()
    ' Create a Visual Basic Collection object.
    Dim names As New Microsoft.VisualBasic.Collection()
    Dim key As Integer
    Dim msg As String
    Dim name As String
    Dim nameList As String = ""
    ' 1. Get names from the user to add to the collection.
    Do
        Dim inst As New nameClass()
        key += 1
        msg = "Please enter a name for this object." & vbCrLf &
              "Press Cancel to see names in collection."
        name = InputBox(msg, "Name the Collection items")
        inst.instanceName = name
        ' If user entered a name, add it to the collection.
        If inst.instanceName <> "" Then
            names.Add(inst, CStr(key))
        End If
    Loop Until name = ""
    ' 2. Create and display a list of names from the collection.
    For Each oneInst As nameClass In names
        nameList &= oneInst.instanceName & vbCrLf
    Next oneInst
    MsgBox(nameList, , "Instance Names in names Collection")
    ' 3. Remove elements from the collection without disposing of the collection.
    For count As Integer = 1 To names.Count
        names.Remove(1)
        ' Since Visual Basic collections are reindexed automatically, 
        ' remove the first member on each iteration.
    Next count
End Sub

Observações

O objeto Visual Basic Collection fornece uma forma conveniente de se referir a um grupo relacionado de itens como um único objeto. Os itens, ou elementos, numa coleção só precisam de estar relacionados pelo facto de existirem na coleção. Os elementos de uma coleção não têm de partilhar o mesmo tipo de dados.

Pode criar uma coleção da mesma forma que cria outros objetos, como o exemplo seguinte ilustra.

Dim coll As New Microsoft.VisualBasic.Collection()

Depois de criar uma coleção, pode fazer qualquer uma das seguintes:

• Adiciona um elemento ao Add método.

• Remova um elemento com o Remove método.

• Remova todos os elementos com o Clear método.

• Descubra quantos elementos a coleção contém com a Count propriedade.

• Verifique se um elemento específico está presente no Contains método.

• Devolva um elemento específico da coleção com a Item[] propriedade.

• Itera por toda a coleção com o For Each... Próxima declaração.

  Note

  Embora o objeto Visual Basic Collection tenha funcionalidades idênticas ao objeto Collection na Visual Basic 6.0, ambos não podem interoperar num ambiente COM.

  Atenção

  Iterar através de um Visual Basic Collection não é um procedimento seguro para threads. Mesmo que a coleção esteja sincronizada, outros threads podem ainda modificar a coleção, fazendo com que o enumerador lance uma exceção. Para garantir a segurança dos threads durante a enumeração, ou bloqueie a coleção ou detete as exceções resultantes de alterações feitas por outros threads. Para mais informações sobre bloqueio de um elemento de programação, consulte Instrução SyncLock.