Práticas recomendadas de FinOps para Web

Este artigo descreve uma coleção de práticas comprovadas de FinOps para serviços Web. Ele fornece estratégias para otimizar custos, melhorar a eficiência e usar consultas do Azure Resource Graph (ARG) para obter informações sobre seus recursos da Web. Seguindo essas práticas, você pode garantir que seus serviços Web sejam econômicos e estejam alinhados com os objetivos financeiros da sua organização.

Serviço de Aplicações

As seções a seguir fornecem consultas ARG para o Serviço de Aplicativo. Essas consultas ajudam você a obter informações sobre seus recursos do Serviço de Aplicativo e garantir que eles estejam configurados com as configurações apropriadas. Ao analisar os planos do Serviço de Aplicativo e as recomendações do Assistente do Azure, você pode otimizar seus recursos do Serviço de Aplicativo para obter eficiência de custos.

Consulta: Status do aplicativo Web

Esta consulta ARG recupera o status e as informações básicas de aplicativos Web em seu ambiente do Azure.

Categoria

Monitorização

Consulta

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Remover planos vazios de App Service

Recomendação: Remova planos de Serviços de Aplicações que não tenham aplicações ou funções alojadas para evitar custos desnecessários.

Sobre planos vazios de App Service

Os planos de App Service definem os recursos de computação para as suas aplicações web. Os planos pagos têm custos baseados no SKU configurado e no número de instâncias, independentemente de existirem ou não aplicações alojadas neles. Planos vazios podem acumular-se durante o desenvolvimento ou quando as aplicações são movidas entre planos. Remover planos não utilizados elimina custos desnecessários.

Identificar planos de serviços de aplicações vazios

Use a seguinte consulta ARG para identificar planos de Serviços de Aplicações sem aplicações alojadas.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Consulta: Detalhes do plano do Serviço de Aplicações

Esta consulta ARG recupera informações detalhadas sobre os Planos do Serviço de Aplicativo do Azure em seu ambiente do Azure.

Categoria

Gestão de recursos

Consulta

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Enviar comentários

Dê-nos a sua opinião com uma breve avaliação. Usamos essas análises para melhorar e expandir as ferramentas e os recursos do FinOps.

Se você está procurando algo específico, vote em uma ideia existente ou crie uma nova. Partilhe ideias com outras pessoas para obter mais votos. Focamo-nos nas ideias mais votadas.

Conteúdos relacionados

Recursos relacionados:

• Estrutura FinOps

Soluções relacionadas:

• Relatórios do Power BI do kit de ferramentas FinOps
• Centros FinOps
• Livros de exercícios FinOps
• Motor de otimização