Aanbevolen procedures voor FinOps voor web

In dit artikel vindt u een overzicht van een verzameling bewezen FinOps-procedures voor webservices. Het biedt strategieën voor het optimaliseren van kosten, het verbeteren van de efficiëntie en het gebruik van ARG-query's (Azure Resource Graph) om inzicht te krijgen in uw webresources. Door deze procedures te volgen, kunt u ervoor zorgen dat uw webservices rendabel zijn en zijn afgestemd op de financiële doelstellingen van uw organisatie.

App-dienst

De volgende secties bevatten ARG-query's voor App Service. Met deze query's krijgt u inzicht in uw App Service-resources en zorgt u ervoor dat deze zijn geconfigureerd met de juiste instellingen. Door App Service-plannen te analyseren en aanbevelingen van Azure Advisor op te doen, kunt u uw App Service-resources optimaliseren voor kostenefficiëntie.

Vraag: De status van webtoepassing

Met deze ARG-query worden de status en basisinformatie van webtoepassingen in uw Azure-omgeving opgehaald.

Categorie

Controleren

Vraag

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Lege App Service-plannen verwijderen

Aanbeveling: Verwijder App Service-plannen waarvoor geen apps of functies worden gehost om onnodige kosten te voorkomen.

Over lege App Service-abonnementen

App Service-plannen definiëren de rekenresources voor uw web-apps. Betaalde abonnementen brengen kosten in rekening op basis van hun geconfigureerde SKU en het aantal exemplaren, ongeacht of er apps op deze worden gehost. Lege abonnementen kunnen zich tijdens de ontwikkeling opstapelen of wanneer apps tussen abonnementen worden verplaatst. Het verwijderen van ongebruikte plannen elimineert onnodige kosten.

Lege App Service-plannen identificeren

Gebruik de volgende ARG-query om App Service-plannen zonder gehoste apps te identificeren.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Vraag: App Service-plan details

Deze ARG-query haalt gedetailleerde informatie op over Azure-app serviceplannen in uw Azure-omgeving.

Categorie

Resourcebeheer

Vraag

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Feedback geven

Laat ons weten hoe we het doen met een korte recensie. We gebruiken deze beoordelingen om FinOps-hulpprogramma's en -resources te verbeteren en uit te breiden.

Als u op zoek bent naar iets specifieks, stem dan op een bestaande of maak een nieuw idee. Deel ideeën met anderen om meer stemmen te krijgen. We richten ons op ideeën met de meeste stemmen.

Gerelateerde inhoud

Gerelateerde resources:

• FinOps Framework

Verwante oplossingen:

• Power BI-rapporten voor FinOps Toolkit
• finops-hubs
• FinOps-werkmappen
• Optimalisatie-engine