Aanbevolen procedures voor FinOps voor Opslag

In dit artikel vindt u een overzicht van een verzameling bewezen FinOps-procedures voor opslagservices. Het biedt strategieën voor het optimaliseren van kosten, het verbeteren van de efficiëntie en het gebruik van ARG-query's (Azure Resource Graph) om inzicht te krijgen in uw opslagresources. Door deze procedures te volgen, kunt u ervoor zorgen dat uw opslagservices rendabel zijn en zijn afgestemd op de financiële doelstellingen van uw organisatie.

Reservekopie

De volgende secties bevatten ARG-query's voor back-upservices. Deze query's helpen u inzicht te krijgen in uw back-upresources en ervoor te zorgen dat ze zijn geconfigureerd met de juiste instellingen. Door back-upitems te analyseren en niet-actieve back-ups te identificeren, kunt u uw back-upservices optimaliseren voor kostenefficiëntie.

Query: Niet-actieve back-ups

Deze ARG-query analyseert back-upitems in Azure Recovery Services-kluizen en identificeert back-upitems die langer dan 90 dagen niet zijn geback-upt.

Categorie

Optimalisatie

Vraag

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Query: Recovery Services-kluizen weergeven

Deze Arg-query (Azure Resource Graph) haalt details van Azure Recovery Services-kluizen op. De query bevat ook informatie over de SKU-laag, redundantie-instellingen en andere relevante metagegevens.

Categorie

Optimalisatie

Vraag

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Schijven

Azure beheerde schijven zijn opslagvolumes op blokniveau die worden beheerd door Azure en worden gebruikt met virtuele machines. Beheerde schijven bieden hoge beschikbaarheid, schaalbaarheid en beveiliging voor uw VM-workloads.

Gerelateerde resources:

• Prijzen voor beheerde schijven
• Documentatie voor beheerde schijven

Niet-gekoppelde schijven verwijderen

Aanbeveling: Verwijder of downgrade niet-gekoppelde beheerde schijven om onnodige opslagkosten te voorkomen.

Over niet-gekoppelde schijven

Wanneer een VIRTUELE machine wordt verwijderd, worden de bijbehorende beheerde schijven mogelijk niet automatisch verwijderd. Voor deze niet-gekoppelde (zwevende) schijven blijven opslagkosten in rekening worden gebracht op basis van het schijftype en de grootte. De query sluit schijven uit die zich in de actieve SAS-overdrachtsmodus bevinden of zijn Azure Site Recovery replica- of seed-schijven, omdat deze naar verwachting tijdelijk niet worden gekoppeld.

Niet-gekoppelde schijven identificeren

Gebruik de volgende ARG-query om niet-gekoppelde beheerde schijven te identificeren.

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Query: Momentopname van schijf ouder dan 30 dagen

Deze ARG-query identificeert momentopnamen van schijven die ouder zijn dan 30 dagen.

Categorie

Optimalisatie

Vraag

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Premium-momentopnamen downgraden

Aanbeveling: Gebruik Standard-opslag voor momentopnamen van beheerde schijven in plaats van Premium om de opslagkosten te verlagen.

Over Premium-momentopnamen

Voor momentopnamen van beheerde schijven die zijn opgeslagen in Premium-opslag, worden hogere kosten in rekening gebracht dan Standard-opslag. In de meeste gevallen is voor momentopnamen de prestaties van Premium-opslag niet vereist, omdat ze worden gebruikt voor back-up en herstel, niet voor actieve I/O. Downgraden naar Standard-opslag kan de kosten van momentopnamen aanzienlijk verlagen zonder dat dit van invloed is op hun functionaliteit.

Premium-momentopnamen identificeren

Gebruik de volgende ARG-query om momentopnamen van beheerde schijven te identificeren met behulp van Premium-opslag.

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Opslagrekeningen

Azure Storage accounts bieden een unieke naamruimte in Azure voor uw gegevens. Opslagaccounts zijn door verschillende generaties ontwikkeld en het gebruik van verouderde accounttypen kan de toegang tot nieuwere functies en optimalisaties beperken.

Gerelateerde resources:

• Productpagina van opslagaccount
• Prijzen van opslagaccounts
• Documentatie voor opslagaccounts

Oude opslagaccounts upgraden

Aanbeveling: Werk opslagaccounts bij met GPv1 of BlobStorage naar GPv2 voor betere prijscategorieën, functies en continue ondersteuning.

Over oudere opslagaccounts

Opslagaccounts die gebruikmaken van het type GPv1 of BlobStorage bieden geen ondersteuning voor de nieuwste Azure Storage functies, zoals toegangslagen voor blok-blobs, beleid voor levenscyclusbeheer en onveranderbaarheidsbeleid. GPv2-opslagaccounts bieden dezelfde functies plus extra mogelijkheden tegen concurrerende of lagere prijzen. Microsoft raadt aan om alle GPv1- en BlobStorage-accounts te upgraden naar GPv2.

Verouderde opslagaccounts identificeren

Gebruik de volgende ARG-query om opslagaccounts te identificeren die nog steeds gebruikmaken van het type GPv1 of BlobStorage.

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Feedback geven

Laat ons weten hoe we het doen met een korte recensie. We gebruiken deze beoordelingen om FinOps-hulpprogramma's en -resources te verbeteren en uit te breiden.

Als u op zoek bent naar iets specifieks, stem dan op een bestaande of maak een nieuw idee. Deel ideeën met anderen om meer stemmen te krijgen. We richten ons op ideeën met de meeste stemmen.

Gerelateerde inhoud

Gerelateerde resources:

• FinOps Framework

Verwante oplossingen:

• Power BI-rapporten voor FinOps Toolkit
• FinOps-hubs
• FinOps-werkmappen
• Optimalisatie-engine