Beste praktijken voor FinOps voor netwerken

In dit artikel vindt u een overzicht van bewezen FinOps-procedures voor netwerkservices. Ze richten zich op kostenoptimalisatie, efficiëntieverbeteringen en resource-inzichten.

Azure Firewall

De volgende secties bevatten ARG-query's (Azure Resource Graph) voor Azure Firewall. Met deze query's krijgt u inzicht in uw Azure Firewall-resources en zorgt u ervoor dat deze zijn geconfigureerd met de juiste instellingen. Door gebruikspatronen te analyseren en aanbevelingen van Azure Advisor op te doen, kunt u uw Azure Firewall-configuraties optimaliseren voor kostenefficiëntie.

Query: Analyse van Azure-firewall- en firewallbeleid

Met deze ARG-query worden Azure-firewalls en het bijbehorende firewallbeleid in uw Azure-omgeving geanalyseerd. Het is specifiek gericht op firewalls met een premium-SKU-laag en controleert of de configuraties in hun bijbehorende firewallbeleid gebruikmaken van de premium-functies.

Categorie

Optimalisatie

Vraag

resources
| where type =~ 'Microsoft.Network/azureFirewalls' and properties.sku.tier=="Premium"
| project FWID=id, firewallName=name, SkuTier=tostring(properties.sku.tier), resourceGroup, location
| join kind=inner (
    resources
    | where type =~ 'microsoft.network/firewallpolicies'
    | mv-expand properties.firewalls
    | extend intrusionDetection = tostring(properties.intrusionDetection contains "Alert"
        or properties.intrusionDetection contains "Deny")
    | extend transportSecurity = tostring(properties.transportSecurity contains "keyVaultSecretId")
    | extend FWID = tostring(properties_firewalls.id)
    | where intrusionDetection == "False"
        and transportSecurity == "False"
    | project
        PolicyName = name,
        PolicySKU = tostring(properties.sku.tier),
        intrusionDetection,
        transportSecurity,
        FWID
) on FWID

Query: Analyse van Azure Firewall en bijbehorende subnetten

Met deze ARG-query worden Azure-firewalls en de bijbehorende subnetten in uw Azure-omgeving geanalyseerd. Het biedt inzicht in de subnetten die zijn gekoppeld aan elk Azure Firewall-exemplaar. Optimaliseer het gebruik van Azure Firewall door een centraal exemplaar van Azure Firewall te hebben in het virtuele hubnetwerk of de virtuele WAN-beveiligde hub. Deel vervolgens dezelfde firewall in veel virtuele spoke-netwerken die zijn verbonden met dezelfde hub vanuit dezelfde regio.

Categorie

Optimalisatie

Vraag

resources
| where type =~ 'Microsoft.Network/azureFirewalls' and properties.sku.tier=="Premium"
| project
    FWID=id,
    firewallName=name,
    SkuTier=tostring(properties.sku.tier),
    resourceGroup,
    location
| join kind=inner (
    resources
    | where type =~ 'microsoft.network/firewallpolicies'
    | mv-expand properties.firewalls
    | extend intrusionDetection = tostring(properties.intrusionDetection contains "Alert"
        or properties.intrusionDetection contains "Deny")
    | extend transportSecurity = tostring(properties.transportSecurity contains "keyVaultSecretId")
    | extend FWID=tostring(properties_firewalls.id)
    | where intrusionDetection == "False"
        and transportSecurity == "False"
    | project
        PolicyName = name,
        PolicySKU = tostring(properties.sku.tier),
        intrusionDetection,
        transportSecurity,
        FWID
) on FWID

Application Gateway

Azure Application Gateway is een load balancer voor webverkeer waarmee u verkeer naar uw webtoepassingen kunt beheren. Het biedt routerings- en taakverdelingsservices op toepassingsniveau waarmee u een schaalbare en maximaal beschikbare webfront-end kunt bouwen in Azure.

Gerelateerde resources:

• Productpagina van Application Gateway
• Prijzen voor Application Gateway
• Documentatie voor Application Gateway

Niet-actieve toepassingsgateways verwijderen

Aanbeveling: Verwijder toepassingsgateways die geen back-endpools hebben om onnodige kosten te voorkomen.

Over niet-actieve toepassingsgateways

Toepassingsgateways zonder back-endpooldoelen zijn niet actief om verkeer te routeren en vertegenwoordigen mogelijk ongebruikte resources. Deze inactieve gateways blijven kosten met zich meebrengen, ook al vervullen ze geen functie.

Niet-actieve toepassingsgateways identificeren

Gebruik de volgende ARG-query om toepassingsgateways met lege back-endpools te identificeren.

resources
| where type =~ 'Microsoft.Network/applicationGateways'
| extend
    backendPoolsCount = array_length(properties.backendAddressPools),
    SKUName = tostring(properties.sku.name),
    SKUTier = tostring(properties.sku.tier),
    SKUCapacity = properties.sku.capacity,
    backendPools = properties.backendAddressPools,
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| project id, name, SKUName, SKUTier, SKUCapacity, resourceGroup, subscriptionId
| join (
    resources
    | where type =~ 'Microsoft.Network/applicationGateways'
    | mvexpand backendPools = properties.backendAddressPools
    | extend backendIPCount = array_length(backendPools.properties.backendIPConfigurations)
    | extend backendAddressesCount = array_length(backendPools.properties.backendAddresses)
    | extend backendPoolName = backendPools.properties.backendAddressPools.name
    | summarize
        backendIPCount = sum(backendIPCount),
        backendAddressesCount = sum(backendAddressesCount)
        by id
) on id
| project-away id1
| where (backendIPCount == 0 or isempty(backendIPCount))
    and (backendAddressesCount==0 or isempty(backendAddressesCount))
| order by id asc

Klassieke toepassingsgateways upgraden

Aanbeveling: Upgrade Application Gateway v1 SKU naar v2 vóór de buitengebruikstellingsdatum van v1 om verbeterde functies voor ondersteuning en toegang te behouden.

Over klassieke toepassingsgateways

Application Gateway v1 SKU (Standard en WAF) wordt buiten gebruik gesteld. De v2-SKU biedt automatisch schalen, zoneredundantie en verbeterde prestaties. Migreren naar v2 zorgt voor continue ondersteuning en kan kosten verlagen via automatisch schalen, waardoor het aantal exemplaren automatisch wordt aangepast op basis van verkeer.

Klassieke toepassingsgateways identificeren

Gebruik de volgende ARG-query om toepassingsgateways te identificeren die nog steeds gebruikmaken van de v1-SKU.

resources
| where type =~ 'microsoft.network/applicationgateways'
| where properties.sku.tier in ('Standard', 'WAF')
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUTier = tostring(properties.sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

DDoS Protection

Azure DDoS Protection biedt tegenmaatregelen tegen de meest geavanceerde DDoS-bedreigingen. Het biedt verbeterde DDoS-risicobeperkingsmogelijkheden voor uw toepassing en resources die zijn geïmplementeerd in uw virtuele netwerken.

Gerelateerde resources:

• Azure DDoS Protection-productpagina
• Azure DDoS Protection-prijzen
• Documentatie voor Azure DDoS Protection

Niet-gekoppelde DDoS-beveiligingsplannen verwijderen

Aanbeveling: Verwijder DDoS-beveiligingsplannen die niet zijn gekoppeld aan een virtueel netwerk om onnodige kosten te voorkomen.

Over niet-gekoppelde DDoS-beveiligingsplannen

Voor DDoS-beveiligingsplannen worden vaste maandelijkse kosten in rekening gebracht. Plannen die niet aan een virtueel netwerk zijn gekoppeld, bieden geen beveiliging, maar genereren nog steeds kosten. Het verwijderen van ongebruikte plannen elimineert onnodige uitgaven.

Niet-gekoppelde DDoS-beveiligingsplannen identificeren

Gebruik de volgende ARG-query om DDoS-beveiligingsplannen te identificeren die niet zijn gekoppeld aan een virtueel netwerk.

resources
| where type =~ 'microsoft.network/ddosprotectionplans'
| where isnull(properties.virtualNetworks) or array_length(properties.virtualNetworks) == 0
| project
    ResourceId = tolower(id),
    ResourceName = name,
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

ExpressRoute

Met Azure ExpressRoute kunt u uw on-premises-netwerken uitbreiden naar de Microsoft-cloud via een privéverbinding. Voor ExpressRoute-circuits worden maandelijkse kosten in rekening gebracht op basis van de SKU en de ingerichte bandbreedte.

Gerelateerde resources:

• Productpagina van ExpressRoute
• ExpressRoute-prijzen
• ExpressRoute-documentatie

Niet-ingerichte ExpressRoute-circuits verwijderen

Aanbeveling: Verwijder of provisioneer ExpressRoute-circuits die zich in een niet-geprovisioneerde status bevinden om onnodige kosten te voorkomen.

Info over niet-geactiveerde ExpressRoute-circuits

ExpressRoute-circuits die in de status 'NotProvisioned' blijven, verwerken niet actief verkeer, maar er worden nog steeds maandelijks kosten in rekening gebracht. Deze circuits zijn mogelijk aangemaakt, maar nooit afgerond bij de serviceprovider. Door ze te identificeren en te verwijderen, worden onnodige kosten weggenomen.

Niet-geconfigureerde ExpressRoute-circuits identificeren

Gebruik de volgende ARG-query om ExpressRoute-circuits in een niet-geprovisioneerde status te identificeren.

resources
| where type =~ 'Microsoft.Network/expressRouteCircuits'
    and properties.serviceProviderProvisioningState == "NotProvisioned"
| extend
    ServiceLocation = tostring(properties.serviceProviderProperties.peeringLocation),
    ServiceProvider = tostring(properties.serviceProviderProperties.serviceProviderName),
    BandwidthInMbps = tostring(properties.serviceProviderProperties.bandwidthInMbps)
| project
    ERId = id,
    ERName = name,
    ERRG = resourceGroup,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    SKUFamily = tostring(sku.family),
    ERLocation = location,
    ServiceLocation,
    ServiceProvider,
    BandwidthInMbps

Ladingsverdelaar

Azure Load Balancer werkt op laag 4 van het OSI-model en distribueert inkomend verkeer over instanties van gezonde back-endpools. Het biedt hoge beschikbaarheid door de gezondheid van backend-instanties te bewaken en verkeer automatisch weg te leiden van instanties die niet goed functioneren.

Gerelateerde resources:

• Load Balancer productpagina
• Prijzen voor load balancers
• Documentatie voor Load Balancer

Niet-actieve load balancers verwijderen

Aanbeveling: verwijder load balancers die geen back-endpools hebben om onnodige kosten te voorkomen.

Over niet-actieve load balancers

Load balancers zonder doelen in de back-endpool verdelen niet actief verkeer en kunnen ongebruikte bronnen zijn. Standard SKU-load balancers brengen kosten in rekening, zelfs wanneer ze niet actief zijn, dus het verwijderen van ongebruikte exemplaren kan onnodige uitgaven verminderen.

Niet-actieve load balancers identificeren

Gebruik de volgende ARG-query om Standard SKU-load balancers met lege back-endpools te identificeren.

resources
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend SKUName = tostring(sku.name)
| extend SKUTier = tostring(sku.tier)
| extend location,backendAddressPools = properties.backendAddressPools
| where type =~ 'microsoft.network/loadbalancers'
    and array_length(backendAddressPools) == 0
    and sku.name!='Basic'
| order by id asc
| project
    id,
    name,
    SKUName,
    SKUTier,
    backendAddressPools,
    location,
    resourceGroup,
    subscriptionId

Basic load balancers upgraden

Aanbeveling: Werk load balancers bij met behulp van de buiten gebruik gestelde Basic-SKU naar Standard voor betere prestaties, beveiliging en continue ondersteuning.

Info over Basic Load Balancers

De Basic-SKU voor Azure Load Balancer is op 30 september 2025 buiten gebruik gesteld. Basic Load Balancers bieden geen SLA, bieden geen ondersteuning voor beschikbaarheidszones en hebben beperkte diagnostische mogelijkheden. Upgraden naar standard-SKU biedt verbeterde betrouwbaarheid, prestaties en beveiligingsfuncties.

Basic Load Balancers identificeren

Gebruik de volgende ARG-query om load balancers te identificeren met behulp van de Basic SKU.

resources
| where type =~ 'microsoft.network/loadbalancers'
| where sku.name =~ 'Basic'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

NAT-gateway

Azure NAT Gateway biedt uitgaande internetverbinding voor virtuele netwerken. NAT-gateways vereenvoudigen de uitgaande internetverbinding door een beheerde, maximaal beschikbare SNAT-service te bieden.

Gerelateerde resources:

• productpagina van NAT Gateway
• Prijzen voor NAT Gateway
• Documentatie voor NAT Gateway

Verweesde NAT-gateways verwijderen

Aanbeveling: VERWIJDER NAT-gateways die niet aan een subnet zijn gekoppeld om onnodige kosten te voorkomen.

Over zwevende NAT-gateways

VOOR NAT-gateways worden uurkosten en gegevensverwerkingskosten in rekening gebracht. Gateways die niet aan een subnet zijn gekoppeld, bieden geen uitgaande connectiviteit en vertegenwoordigen verspilde uitgaven. Deze zwevende gateways kunnen blijven bestaan nadat een subnet of virtueel netwerk opnieuw is geconfigureerd.

Zwevende NAT-gateways identificeren

Gebruik de volgende ARG-query om NAT-gateways te identificeren die niet zijn gekoppeld aan een subnet.

resources
| where type == "microsoft.network/natgateways"
| where isnull(properties.subnets) or array_length(properties.subnets) == 0
| project
    id,
    GWName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Location = location,
    resourceGroup = tostring(strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)),
    subnets = properties.subnets,
    subscriptionId

Netwerkinterface

Azure netwerkinterfaces (NIC's) stellen Azure VM's in staat om te communiceren met internet, Azure en on-premises resources. NIC’s brengen geen directe kosten met zich mee, maar verweesde NIC’s kunnen duiden op gemiste mogelijkheden om op te schonen en het resourcebeheer ingewikkelder maken.

Niet-gekoppelde netwerkinterfaces verwijderen

Aanbeveling: verwijder netwerkinterfaces die niet zijn gekoppeld aan een virtuele machine of privé-eindpunt om uw omgeving schoon te houden en beheeroverhead te verminderen.

Over niet-gekoppelde netwerkinterfaces

Wanneer een VIRTUELE machine wordt verwijderd, worden de bijbehorende netwerkinterfaces mogelijk niet automatisch opgeschoond. Deze verweesde NIC's kunnen zich na verloop van tijd ophopen, waardoor uw omgeving rommelig wordt en mogelijk bijbehorende resources, zoals openbare IP-adressen, behouden blijven. Hoewel NIC's geen directe kosten met zich meebrengen, vereenvoudigt het opschonen ervan het resourcebeheer en kan het andere verweesde resources aan het licht brengen.

Niet-gekoppelde netwerkinterfaces identificeren

Gebruik de volgende ARG-query om netwerkinterfaces te identificeren die niet zijn gekoppeld aan een VIRTUELE machine of privé-eindpunt.

resources
| where type =~ 'microsoft.network/networkinterfaces'
| where isnull(properties.virtualMachine) and isnull(properties.privateEndpoint)
| project
    ResourceId = tolower(id),
    ResourceName = name,
    PrivateIP = tostring(properties.ipConfigurations[0].properties.privateIPAddress),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Netwerkbeveiligingsgroep

Netwerkbeveiligingsgroepen (NSG's) filteren netwerkverkeer van en naar Azure resources in een virtueel netwerk. NSG's bevatten beveiligingsregels die binnenkomend en uitgaand netwerkverkeer toestaan of weigeren.

Lege netwerkbeveiligingsgroepen verwijderen

Aanbeveling: Verwijder netwerkbeveiligingsgroepen die niet zijn gekoppeld aan een netwerkinterface of subnet om uw omgeving te vereenvoudigen en beheeroverhead te verminderen.

Over lege netwerkbeveiligingsgroepen

NSG's die niet zijn gekoppeld aan een netwerkinterface of subnet, filteren niet actief verkeer. Deze ongebruikte resources kunnen zich ophopen tijdens wijzigingen in de infrastructuur, waardoor er rommel ontstaat en beveiligingsaudits ingewikkelder worden. Als u ze verwijdert, vereenvoudigt u het netwerkbeheer en zorgt u voor een schone omgeving.

Lege netwerkbeveiligingsgroepen identificeren

Gebruik de volgende ARG-query om NSG's te identificeren die niet zijn gekoppeld aan een netwerkinterface of subnet.

resources
| where type =~ 'microsoft.network/networksecuritygroups'
| where isnull(properties.networkInterfaces) and isnull(properties.subnets)
| project
    ResourceId = tolower(id),
    ResourceName = name,
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Privé-DNS

De volgende sectie bevat een ARG-query voor Privé-DNS. Het helpt u inzicht te krijgen in uw Privé-DNS resources en ervoor te zorgen dat ze zijn geconfigureerd met de juiste instellingen.

Query: Privé-DNS

Met deze ARG-query worden Privé-DNS-zones in uw Azure-omgeving geanalyseerd om te identificeren welke geen virtuele netwerkkoppelingen hebben.

Categorie

Optimalisatie

Vraag

resources
| where type == "microsoft.network/privatednszones"
    and properties.numberOfVirtualNetworkLinks == 0
| project id, PrivateDNSName=name,
    NumberOfRecordSets = tostring(properties.numberOfRecordSets),
    resourceGroup = tostring(strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)),
    vNets = tostring(properties.properties.numberOfVirtualNetworkLinks),
    subscriptionId

Openbaar IP-adres

Azure openbare IP-adressen stellen Azure resources in staat om te communiceren met internet en andere openbare Azure-services. Openbare IP-adressen worden toegewezen aan resources zoals virtuele machines, load balancers en toepassingsgateways. Voor statische openbare IP-adressen worden kosten in rekening gebracht, ongeacht of ze zijn gekoppeld aan een resource.

Gerelateerde resources:

• Prijzen voor openbare IP-adressen
• Documentatie over openbare IP-adressen

Openbare IP-adressen van Basic upgraden

Aanbeveling: Upgrade openbare IP-adressen met behulp van de buiten gebruik gestelde Basic-SKU naar Standard voor betere beveiliging en continue ondersteuning.

Over openbare IP-adressen van Basic

De Basic-SKU voor Azure openbare IP-adressen is op 30 september 2025 buiten gebruik gesteld. Standaard openbare IP-adressen hebben geen zoneredundantie, bieden geen ondersteuning voor routeringsvoorkeur en zijn standaard open voor inkomend verkeer. Een upgrade naar Standard SKU biedt zoneredundantie, standaard beveiligd gedrag (standaard gesloten voor inkomend verkeer) en ondersteuning voor routeringsvoorkeuren.

Openbare IP-adressen van basic identificeren

Gebruik de volgende ARG-query om openbare IP-adressen te identificeren met behulp van de Basic SKU.

resources
| where type =~ 'microsoft.network/publicipaddresses'
| where sku.name =~ 'Basic'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Niet-actieve openbare IP-adressen verwijderen

Aanbeveling: verwijder niet-gekoppelde statische openbare IP-adressen om onnodige netwerkkosten te voorkomen.

Over niet-actieve openbare IP-adressen

Voor statische openbare IP-adressen worden kosten in rekening gebracht, ongeacht of deze zijn gekoppeld aan een resource. Niet-gekoppelde openbare IP-adressen kunnen zich in de loop van de tijd verzamelen wanneer resources worden verwijderd, maar de bijbehorende openbare IP-adressen blijven achter. Het identificeren en verwijderen van deze niet-gebruikte resources kan onnodige kosten verminderen.

Niet-actieve openbare IP-adressen identificeren

Gebruik de volgende ARG-query om niet-gekoppelde statische openbare IP-adressen te identificeren, inclusief adressen die zijn gekoppeld aan niet-gekoppelde netwerkinterfaces.

resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
    and isempty(properties.ipConfiguration)
    and isempty(properties.natGateway)
    and properties.publicIPAllocationMethod =~ 'Static'
| extend
    PublicIpId = id,
    IPName = name,
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    SKUName = sku.name,
    Location = location,
    resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project PublicIpId, IPName, SKUName, resourceGroup, Location, AllocationMethod, subscriptionId
| union (
    Resources
    | where type =~ 'microsoft.network/networkinterfaces'
        and isempty(properties.virtualMachine)
        and isnull(properties.privateEndpoint)
        and isnotempty(properties.ipConfigurations)
    | extend IPconfig = properties.ipConfigurations
    | mv-expand IPconfig
    | extend PublicIpId= tostring(IPconfig.properties.publicIPAddress.id)
    | project PublicIpId
    | join (
        resource
        | where type =~ 'Microsoft.Network/publicIPAddresses'
        | extend
            PublicIpId = id,
            IPName = name,
            AllocationMethod = tostring(properties.publicIPAllocationMethod),
            SKUName = sku.name,
            resourceGroup,
            Location = location
    ) on PublicIpId
    | project
        PublicIpId,
        IPName,
        SKUName,
        resourceGroup,
        Location,
        AllocationMethod,
        subscriptionId
)

Query: Routeringsmethode voor openbare IP-adressen identificeren

Deze ARG-query analyseert openbare IP-adressen en identificeert de routeringsmethode, toewijzingsmethode en SKU. Het analyseert ook andere details van openbare IP-adressen die zijn gekoppeld aan een IP-configuratie.

Categorie

Optimalisatie

Vraag

resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
    and isnotempty(properties.ipConfiguration)
| where tostring(properties.ipTags) == "[]"
| extend
    PublicIpId = id,
    RoutingMethod = id,
    IPName = name,
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    SKUName = sku.name,
    Location = location,
    resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project
    PublicIpId,
    IPName,
    RoutingMethod,SKUName,
    resourceGroup,
    Location,
    AllocationMethod,
    subscriptionId

Query: Het DDoS-beveiligingsbeleid van openbare IP-adressen controleren

Als u minder dan 15 openbare IP-resources wilt beveiligen, is de IP-beveiligingslaag de rendabeler optie. Als u echter meer dan 15 openbare IP-resources hebt om te beveiligen, wordt de netwerkbeveiligingslaag rendabeler.

Categorie

Optimalisatie

Vraag

resources
| where type == "microsoft.network/publicipaddresses"
| project ddosProtection = tostring(properties.ddosSettings), name
| where ddosProtection has "Enabled"
| count
| project TotalIpsProtected = Count
| extend CheckIpsProtected = iff(TotalIpsProtected >= 15, "Enable Network Protection tier", "Enable PIP DDoS Protection")

Gateway voor een virtueel netwerk

Azure Virtual Network Gateways bieden cross-premises connectiviteit tussen uw Azure virtuele netwerken en on-premises infrastructuur. Gateways brengen uurkosten in rekening op basis van hun SKU.

Gerelateerde resources:

• VPN Gateway prijzen
• Documentatie voor VPN Gateway

Niet-actieve VNet-gateways verwijderen

Aanbeveling: verwijder virtuele netwerkgateways die geen actieve verbindingen hebben om onnodige kosten te voorkomen.

Over niet-actieve VNet-gateways

Virtuele netwerkgateways brengen kosten per uur met zich mee op basis van hun SKU-niveau, ongeacht of ze daadwerkelijk worden gebruikt. Gateways zonder verbindingen bieden geen cross-premises connectiviteit en vertegenwoordigen verspilde uitgaven. Deze niet-actieve gateways kunnen na een migratie blijven bestaan of wanneer de connectiviteitsvereisten veranderen.

Niet-actieve VNet-gateways identificeren

Gebruik de volgende ARG-query om gateways van virtuele netwerken te identificeren zonder actieve verbindingen.

resources
| where type == "microsoft.network/virtualnetworkgateways"
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project id, GWName=name, resourceGroup, location, subscriptionId
| join kind = leftouter(
    resources
    | where type == "microsoft.network/connections"
    | extend id = tostring(properties.virtualNetworkGateway1.id)
    | project id
) on id
| where isempty(id1)
| project
    id,
    GWName,
    resourceGroup,
    location,
    subscriptionId,
    status=id

Feedback geven

Laat ons weten hoe we het doen met een korte recensie. We gebruiken deze beoordelingen om FinOps-hulpprogramma's en -resources te verbeteren en uit te breiden.

Als u op zoek bent naar iets specifieks, stem dan op een bestaande of maak een nieuw idee. Deel ideeën met anderen om meer stemmen te krijgen. We richten ons op ideeën met de meeste stemmen.

Gerelateerde inhoud

Gerelateerde resources:

• FinOps Framework

Verwante oplossingen:

• Power BI-rapporten voor FinOps Toolkit
• FinOps-hubs
• FinOps-werkmappen
• Optimalisatie-engine