Opnemen uit query (.set, .append, .set-or-append, .set-or-replace)

Schakelen tussen services met behulp van de vervolgkeuzelijst Versie . Meer informatie over navigatie.
Van toepassing op: ✅ Microsoft Fabric ✅ Azure Data Explorer

Met deze opdrachten wordt een query of een beheeropdracht uitgevoerd en worden de resultaten van de query opgenomen in een tabel. Het verschil tussen deze opdrachten is hoe ze bestaande of niet-bestaande tabellen en gegevens behandelen.

Als u een opname wilt annuleren vanuit de queryopdracht, raadpleegt cancel operationu .

Permissions

Als u verschillende acties voor een tabel wilt uitvoeren, hebt u specifieke machtigingen nodig:

• Als u rijen wilt toevoegen aan een bestaande tabel met behulp van de .append opdracht, hebt u minimaal De machtigingen van Table Ingestor nodig.
• Als u een nieuwe tabel wilt maken met behulp van de verschillende .set opdrachten, hebt u minimaal databasegebruikersmachtigingen nodig.
• Als u rijen in een bestaande tabel wilt vervangen met behulp van de .set-or-replace opdracht, hebt u minimaal machtigingen voor tabelbeheerder nodig.

Zie Kusto-toegangsbeheer op basis van rollen voor meer informatie over machtigingen.

Syntaxis

(.set | .append | .set-or-append | .set-or-replace) [async] tableName [with(=propertyName propertyValue [, ...]] )<|queryOrCommand

Meer informatie over syntaxisconventies.

Parameterwaarden

Prestatietips

• Stel de distributed eigenschap in op true als de hoeveelheid gegevens die door de query wordt geproduceerd, groter is dan één gigabyte (GB) en geen serialisatie vereist. Vervolgens kunnen meerdere knooppunten parallel uitvoer produceren. Gebruik deze vlag niet wanneer queryresultaten klein zijn, omdat er mogelijk onnodig veel kleine gegevensshards worden gegenereerd.
• Gegevensopname is een resource-intensieve bewerking die invloed kan hebben op gelijktijdige activiteiten in de database, waaronder het uitvoeren van query's. Vermijd het uitvoeren van te veel opnameopdrachten tegelijk.
• Beperk de gegevens voor opname tot minder dan één GB per opnamebewerking. Gebruik indien nodig meerdere opnameopdrachten.

Ondersteunde opname-eigenschappen

Overwegingen voor schema's

• .set-or-replace behoudt het schema, tenzij een van extend_schema of recreate_schema de opname-eigenschappen is ingesteld op true.
• .set-or-append en .append opdrachten behouden het schema, tenzij de extend_schema opname-eigenschap is ingesteld op true.
• Het resultaatsetschema overeenkomt met dat van de doeltabel is gebaseerd op de kolomtypen. Er is geen overeenkomende kolomnamen. Zorg ervoor dat de kolommen van het queryresultaatschema dezelfde volgorde hebben als de tabel, anders worden gegevens opgenomen in de verkeerde kolommen.

Tekenbeperking

De opdracht mislukt als de query een entiteitsnaam met het $ teken genereert. De entiteitsnamen moeten voldoen aan de naamgevingsregels, dus het $ teken moet worden verwijderd om de opnameopdracht te laten slagen.

In de volgende query genereert de search operator bijvoorbeeld een kolom $table. Als u de queryresultaten wilt opslaan, gebruikt u projectnaam om de naam van de kolom te wijzigen.

.set Texas <| search State has 'Texas' | project-rename tableName=$table

Retouren

Retourneert informatie over de gebieden die zijn gemaakt vanwege de .set of .append opdracht.

Voorbeelden

Tabel maken en bijwerken vanuit querybron

Met de volgende query wordt de RecentErrors tabel gemaakt met hetzelfde schema als LogsTable. Het wordt RecentErrors bijgewerkt met alle foutenlogboeken van LogsTable het afgelopen uur.

.set RecentErrors <|
   LogsTable
   | where Level == "Error" and Timestamp > now() - time(1h)

Tabel maken en bijwerken vanuit querybron met behulp van de gedistribueerde vlag

In het volgende voorbeeld wordt een nieuwe tabel gemaakt met de naam OldExtents in de database, asynchroon. De gegevensset is naar verwachting groter dan één GB (meer dan ongeveer één miljoen rijen), zodat de gedistribueerde vlag wordt gebruikt. Het wordt bijgewerkt OldExtents met ExtentId vermeldingen uit de MyExtents tabel die meer dan 30 dagen geleden zijn gemaakt.

.set async OldExtents with(distributed=true) <|
   MyExtents 
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Gegevens toevoegen aan tabel

In het volgende voorbeeld ExtentId worden vermeldingen in de MyExtents tabel gefilterd die meer dan 30 dagen geleden zijn gemaakt en worden de vermeldingen toegevoegd aan de OldExtents tabel met gekoppelde tags.

.append OldExtents with(tags='["TagA","TagB"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Een tabel maken of toevoegen met mogelijk bestaande getagde gegevens

In het volgende voorbeeld wordt de OldExtents tabel asynchroon toegevoegd of gemaakt. ExtentId Hiermee worden vermeldingen in de MyExtents tabel gefilterd die meer dan 30 dagen geleden zijn gemaakt en worden de tags opgegeven die moeten worden toegevoegd aan de nieuwe gebieden met ingest-by:myTag. De ingestIfNotExists parameter zorgt ervoor dat de opname alleen plaatsvindt als de gegevens nog niet bestaan in de tabel met de opgegeven tag.

.set-or-append async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <|
   MyExtents
   | where CreatedOn < now() - time(30d)
   | project ExtentId

Tabel maken of gegevens vervangen door gekoppelde gegevens

De volgende query vervangt de gegevens in de OldExtents tabel of maakt de tabel als deze nog niet bestaat, door ExtentId vermeldingen in de MyExtents tabel die meer dan 30 dagen geleden zijn gemaakt. Tag de nieuwe omvang met ingest-by:myTag als de gegevens nog niet bestaan in de tabel met de opgegeven tag.

.set-or-replace async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

Gegevens toevoegen aan gekoppelde gegevens

In het volgende voorbeeld worden gegevens asynchroon aan de OldExtents tabel toegevoegd met behulp van ExtentId vermeldingen uit de MyExtents tabel die meer dan 30 dagen geleden zijn gemaakt. Hiermee stelt u een specifieke aanmaaktijd in voor de nieuwe gebieden.

.append async OldExtents with(creationTime='2017-02-13T11:09:36.7992775Z') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId     

Voorbeelduitvoer

Hier volgt een voorbeeld van het type uitvoer dat u kunt zien in uw query's.

Verwante inhoud

• gegevensindelingen die worden ondersteund voor opname
• Inlineopname
• Opnemen vanuit opslag