Bicep 배포를 위한 매개 변수 파일 만들기

Bicep 매개 변수 파일의 파일 확장명은 .bicepparam입니다.

여러 환경에 배포하려면 둘 이상의 매개 변수 파일을 만듭니다. 여러 개의 매개 변수 파일을 사용하는 경우 용도에 따라 레이블을 지정합니다. 예를 들어, 리소스를 배포하려면 개발에는 main.dev.bicepparam 레이블을 사용하고 프로덕션에는 main.prod.bicepparam 레이블을 사용합니다.

매개 변수 파일의 일반적인 명명 규칙은 Bicep 파일 이름에 매개 변수를 포함하는 것입니다. 예를 들어, Bicep 파일의 이름이 azuredeploy.bicep인 경우 매개변수 파일의 이름을 azuredeploy.parameters.json로 지정합니다. 이 명명 규칙은 Bicep 파일과 매개 변수 간의 연결을 확인하는 데 도움이 됩니다.

다른 환경에 배포하려면 둘 이상의 매개 변수 파일을 만듭니다. 여러 개의 매개 변수 파일을 사용하는 경우 용도에 따라 레이블을 지정합니다. 예를 들어, 리소스를 배포하려면 개발에는 azuredeploy.parameters-dev.json 레이블을 사용하고 프로덕션에는 azuredeploy.parameters-prod.json 레이블을 사용합니다.

using '<path>/<file-name>.bicep' | using none
extends '<path>/<file-name>.bicepparam' 

type <user-defined-data-type-name> = <type-expression>

var <variable-name> <data-type> = <variable-value>

import {<symbol_name> [as <alias_name>], ...} from '<bicep_file_name>'

param <first-parameter-name> = <first-value>
param <second-parameter-name> = <second-value>
param <third-parameter-name> = <variable-name>

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "<first-parameter-name>": {
      "value": "<first-value>"
    },
    "<second-parameter-name>": {
      "value": "<second-value>"
    }
  }
}

using 'main.bicep'

param storagePrefix
param storageAccountType

using 문은 Bicep 매개 변수 파일을 Bicep 파일에 연결합니다. 여러 매개 변수 파일을 단일 Bicep 파일에 연결할 수 있습니다. 각 매개 변수 파일은 일반적으로 using 문 사용하여 특정 Bicep 파일에 연결됩니다.

매개 변수 파일을 특정 Bicep 파일에 연결하지 않으려면 using none 사용합니다. Bicep CLI 버전 0.31.0 이상에서는 using none 기능을 지원합니다.

자세한 내용은 using 문을 참조하세요.

extends 문은 기본 .bicepparam 파일에서 매개변수를 상속하므로 현재 매개변수 파일에서 매개변수 값을 재사용하고 선택적으로 재정의할 수 있습니다. 자세한 내용은 Extendable 매개 변수 파일을 참조하세요.

Visual Studio Code param 키워드를 입력하면 연결된 Bicep 파일에서 사용 가능한 매개 변수 및 해당 설명을 입력하라는 메시지가 표시됩니다.

param 이름 위에 마우스를 올리면 매개 변수 데이터 형식과 설명을 볼 수 있습니다.

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "storagePrefix": {
    },
    "storageAccountType": {
    }
  }
}

using 'main.bicep'

param storagePrefix = ''
param storageAccountType = ''

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "storagePrefix": {
      "value": ""
    },
    "storageAccountType": {
      "value": ""
    }
  }
}

using 'main.bicep'

param storagePrefix = '' // This value must be provided.
param storageAccountType = '' // This value is optional. Bicep uses default value if not provided.

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "storagePrefix": {
      "value": "" // This value must be provided.
    },
    "storageAccountType": {
      "value": "" // This value is optional. Bicep uses default value if not provided.
    }
  }
}

using 'main.bicep'

param storagePrefix = 'storage'
param storageAccountType = 'Standard_ZRS'

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "storagePrefix": {
      "value": "storage"
    },
    "storageAccountType": {
      "value": "Standard_ZRS"
    }
  }
}

using './main.bicep'

param exampleString = 'test string'
param exampleInt = 2 + 2
param exampleBool = true
param exampleArray = [
  'value 1'
  'value 2'
]
param exampleObject = {
  property1: 'value 1'
  property2: 'value 2'
}

Bicep 구문을 사용하여 개체 및 배열을 선언합니다.

식을 매개 변수 값으로 사용할 수 있습니다. 예를 들면 다음과 같습니다.

using './main.bicep'

param storageName = toLower('MyStorageAccount')
param intValue = 2 + 2

환경 변수를 매개 변수 값으로 참조할 수 있습니다. 예를 들면 다음과 같습니다.

using './main.bicep'

param intFromEnvironmentVariables = int(readEnvironmentVariable('intEnvVariableName'))

변수를 정의하고 사용할 수 있습니다. 파일에서 변수를 사용하려면 .bicepparam 버전 0.21.X 이상을 사용해야 합니다. 다음 예제를 참조하세요.

using './main.bicep'

var storagePrefix = 'myStorage'
param primaryStorageName = '${storagePrefix}Primary'
param secondaryStorageName = '${storagePrefix}Secondary'

using './main.bicep'

var testSettings = {
  instanceSize: 'Small'
  instanceCount: 1
}

var prodSettings = {
  instanceSize: 'Large'
  instanceCount: 4
}

param environmentSettings = {
  test: testSettings
  prod: prodSettings
}

사용자 정의 데이터 형식을 정의할 수 있습니다. 예를 들면 다음과 같습니다.

using './main.bicep'

// Define a reusable type for tags with optional properties
type TagValues = {
  environment: 'dev' | 'test' | 'production'
  project: string
}

var tagsExample TagValues = {
  environment: 'dev'
  project: 'bicep-sample'
}

param tags = tagsExample

Bicep 파일에서 변수, 사용자 정의 데이터 형식 및 사용자 정의 함수를 가져올 수도 있습니다. 자세한 내용은 가져오기를 참조하세요.

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "exampleString": {
      "value": "test string"
    },
    "exampleInt": {
      "value": 4
    },
    "exampleBool": {
      "value": true
    },
    "exampleArray": {
      "value": [
        "value 1",
        "value 2"
      ]
    },
    "exampleObject": {
      "value": {
        "property1": "value1",
        "property2": "value2"
      }
    }
  }
}

Azure CLI 버전 2.53.0 이상 및 Bicep CLI 버전 0.22.X 이상을 사용하여 Bicep 매개 변수 파일을 배포할 수 있습니다. Bicep 매개 변수 파일 내에서 using 문을 사용하면 --template-file 스위치에 Bicep 매개 변수 파일을 지정할 때 --parameters 스위치를 제공할 필요가 없습니다.

az deployment group create \
  --name ExampleDeployment \
  --resource-group ExampleGroup \
  --parameters storage.bicepparam

az deployment group create \
  --name ExampleDeployment \
  --resource-group ExampleGroup \
  --template-file storage.bicep \
  --parameters storage.parameters.json

az deployment group create \
  --name ExampleDeployment \
  --resource-group ExampleGroup \
  --parameters storage.bicepparam \
  --parameters storageAccountType=Standard_LRS

az deployment group create \
  --name ExampleDeployment \
  --resource-group ExampleGroup \
  --template-file storage.bicep \
  --parameters storage.parameters.json \
  --parameters storageAccountType=Standard_LRS

New-AzResourceGroupDeployment `
  -Name ExampleDeployment `
  -ResourceGroupName ExampleResourceGroup `
  -TemplateFile C:\MyTemplates\storage.bicep `
  -TemplateParameterFile C:\MyTemplates\storage.bicepparam

New-AzResourceGroupDeployment `
  -Name ExampleDeployment `
  -ResourceGroupName ExampleResourceGroup `
  -TemplateFile C:\MyTemplates\storage.bicep `
  -TemplateParameterFile C:\MyTemplates\storage.parameters.json

New-AzResourceGroupDeployment `
  -Name ExampleDeployment `
  -ResourceGroupName ExampleResourceGroup `
  -TemplateFile C:\MyTemplates\storage.bicep `
  -TemplateParameterFile C:\MyTemplates\storage.bicepparam `
  -storageAccountType Standard_LRS

New-AzResourceGroupDeployment `
  -Name ExampleDeployment `
  -ResourceGroupName ExampleResourceGroup `
  -TemplateFile C:\MyTemplates\storage.bicep `
  -TemplateParameterFile C:\MyTemplates\storage.parameters.json `
  -storageAccountType Standard_LRS