Interaction.CreateObject(String, String) Método

public static object CreateObject(string ProgId, string ServerName = "");

static member CreateObject : string * string -> obj

Public Function CreateObject (ProgId As String, Optional ServerName As String = "") As Object

Parámetros

Devoluciones

Crea y devuelve una referencia a un objeto COM. CreateObject no se puede usar para crear instancias de clases en Visual Basic a menos que esas clases se expongan explícitamente como componentes COM.

Excepciones

Ejemplos

En el ejemplo siguiente se usa la función CreateObject para crear una hoja de cálculo de Microsoft Excel y guardar la hoja de cálculo en un archivo. Para usar este ejemplo, Excel debe instalarse en el equipo donde se ejecuta este programa. Además, debe agregar una referencia a la biblioteca de tipos desde el cuadro de diálogo COM de la Agregar referencia en el menú Project. El nombre de la biblioteca de tipos varía en función de la versión de Excel instalada en el equipo. Por ejemplo, la biblioteca de tipos de Microsoft Excel 2002 se denomina Microsoft Excel biblioteca de objetos 10.0.

Sub TestExcel()
    Dim xlApp As Microsoft.Office.Interop.Excel.Application
    Dim xlBook As Microsoft.Office.Interop.Excel.Workbook
    Dim xlSheet As Microsoft.Office.Interop.Excel.Worksheet

    xlApp = CType(CreateObject("Excel.Application"), 
                Microsoft.Office.Interop.Excel.Application)
    xlBook = CType(xlApp.Workbooks.Add, 
                Microsoft.Office.Interop.Excel.Workbook)
    xlSheet = CType(xlBook.Worksheets(1), 
                Microsoft.Office.Interop.Excel.Worksheet)

    ' The following statement puts text in the second row of the sheet.
    xlSheet.Cells(2, 2) = "This is column B row 2"
    ' The following statement shows the sheet.
    xlSheet.Application.Visible = True
    ' The following statement saves the sheet to the C:\Test.xls directory.
    xlSheet.SaveAs("C:\Test.xls")
    ' Optionally, you can call xlApp.Quit to close the workbook.
End Sub

Comentarios

Para crear una instancia de un componente COM, asigne el objeto devuelto por CreateObject a una variable de objeto:

Sub CreateADODB()
   Dim adoApp As Object
   adoApp = CreateObject("ADODB.Connection")
End Sub

El tipo de variable de objeto que se usa para almacenar el objeto devuelto puede afectar al rendimiento de la aplicación. Al declarar una variable de objeto con la As Object cláusula se crea una variable que puede contener una referencia a cualquier tipo de objeto. Sin embargo, el acceso al objeto a través de esa variable está enlazado en tiempo de ejecución, es decir, el enlace se produce cuando se ejecuta el programa. Hay muchas razones por las que debe evitar el enlace en tiempo de ejecución, incluido el rendimiento más lento de la aplicación.

Puede crear una variable de objeto que da como resultado un enlace anticipado, es decir, enlazar cuando se compila el programa. Para ello, agregue una referencia a la biblioteca de tipos del objeto desde el cuadro de diálogo COM de la Agregar referencia en el menú Project. A continuación, declare la variable de objeto del tipo específico del objeto. En la mayoría de los casos, es más eficaz usar la Dim instrucción y un ensamblado de interoperabilidad principal para crear objetos que para usar la CreateObject función .

Interacción con código no administrado

Otro problema es que los objetos COM usan código no administrado: código sin la ventaja de Common Language Runtime. Hay un grado justo de complejidad implicado en mezclar el código administrado de Visual Basic con código no administrado de COM. Al agregar una referencia a un objeto COM, Visual Basic busca un ensamblado de interoperabilidad primario (PIA) para esa biblioteca; si encuentra uno, lo usa. Si no encuentra un PIA, crea un ensamblado de interoperabilidad que contiene clases de interoperabilidad locales para cada clase de la biblioteca COM. Para obtener más información, consulte Interoperabilidad COM en aplicaciones de .NET Framework.

Por lo general, debe usar objetos fuertemente enlazados y ensamblados de interoperabilidad primarios siempre que sea posible. En los ejemplos siguientes se usa la función CreateObject con objetos Microsoft Office solo con fines de demostración. Sin embargo, estos objetos son más fáciles de usar y más confiables cuando se usan con el ensamblado de interoperabilidad principal adecuado.

Crear un objeto en un equipo remoto

Puede crear un objeto en un equipo en red remoto pasando el nombre del equipo al ServerName argumento de la CreateObject función. Ese nombre es el mismo que la parte Nombre de máquina de un nombre de recurso compartido: para un recurso compartido denominado "\\MyServer\Public", ServerName es "MyServer".

El código siguiente devuelve el número de versión de una instancia de Excel que se ejecuta en un equipo remoto denominado MyServer:

Sub CreateRemoteExcelObj()
    Dim xlApp As Object
    ' Replace string "\\MyServer" with name of the remote computer.
    xlApp = CreateObject("Excel.Application", "\\MyServer")
    MsgBox(xlApp.Version)
End Sub

Si el nombre del servidor remoto es incorrecto o si no está disponible, se produce un error en tiempo de ejecución.

Creación de objetos de marco

Puede usar la CreateObject función solo para crear un objeto COM. Aunque no hay ningún mecanismo equivalente exacto para crear un objeto .NET Framework, el Activator en el espacio de nombres /System contiene métodos para crear objetos locales o remotos. En concreto, el CreateInstance método o el CreateInstanceFrom método pueden ser útiles.

Consulte también

• GetObject(String, String)
• Exception
• FileNotFoundException
• Activator
• CreateInstance
• CreateInstanceFrom
• instrucción Dim (Visual Basic)
• Instrucción Declare
• Interoperabilidad COM en aplicaciones de .NET Framework
• Interoperación con código no administrado